***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 02, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJT7812   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		        w = 1e-6		level = 3
+  vto = 0.90		       kp = 1.00 )
.model  dds   d(
+   is = 9.234e-14	  	n = 1.115		   rs = 5.707e-1
+   eg = 7.918e-1	     trs1 = -4.428e-3 )
.model  dbody d(
+   is = 9.234e-14		n = 1.115		   rs = 5.707e-1
+   eg = 7.918e-1	     trs1 = -4.428e-3
+  cjo = 1.501e-11		m = 2.216e-1	 	   vj = 3.485e-1
+   bv = 33		      ibv = 250e-6	 
+ tbv1 = 5.765e-4	     tbv2 = 1.045e-7	 	   tt = 25n)
.model  inter  nmos(
+  vto = 0		       kp = 10			level = 1)
.model  dgd   d(
+  cjo = 9.590e-12	        m = 2.259e-1		   vj = 3.905e-1)
.param
+  cgs = 4.194e-11	      cgd = 9.588e-12
+   rd = 3.500e-1	       ra = 1.000e-3	  
+ trd1 = 6.015e-3	     trd2 = 8.505e-6
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.45 ),
+ (2.00 , 1.80 ),
+ (2.50 , 2.05 ),
+ (3.00 , 2.30 ),
+ (4.50 , 2.80 ),
+ (5.00 , 2.90 ),
+ (6.00 , 3.10 ),
+ (8.00 , 3.45 ),
+ (10.0 , 3.70 ),
+ (12.0 , 3.75 ))
egt	  1  2t   value = {4.087e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
